#if 0
// (Run through cpp -P -C first)
#endif

#define PACKAGE     brt.text.parser
#define CLASS       RDFTuples_Parser
#define PARSERBASE  RDFTuplesParserBase

options
{
    // See also ECHAR for false/true.
   JAVA_UNICODE_ESCAPE   = true ;  
   UNICODE_INPUT         = false ; // Whether the input stream is ASCII or Unicode

  STATIC                = false ;
//   DEBUG_PARSER          = true ;
//   DEBUG_TOKEN_MANAGER   = true ;
}


PARSER_BEGIN(CLASS)
/*
 * (c) Copyright 2009 Hewlett-Packard Development Company, LP
 * All rights reserved.
 */

package PACKAGE ;
import com.hp.hpl.jena.graph.* ;
import brt.text.PARSERBASE ;

//@SuppressWarnings("unchecked")
public class CLASS extends PARSERBASE
{
}
PARSER_END(CLASS)

// ---- Parser entry points

void unit() : {}
{
    { startParse() ; }
    (tuple())+
    <EOF>
    { finishParse() ; }
}
 

void tuple() : {Node n ; }
{
   { startTuple() ; }
   ( n = termNode() { emitTerm(n); })*
   <DOT>
   { finishTuple() ; } 
}


Node termNode() : { Node n ; }
{
    (n = IRI() | n = Literal() | n = BlankNode() ) { return n ; }
}

Node IRI() : { String x ;}
{
   x = IRIstr()
   { return createURI(x) ; }
}

String IRIstr() : { Token t ; }
{ 
  t = <IRIREF> 
  { return resolveQuotedIRI(t.image, t.beginLine, t.beginColumn) ; }
}

Node BlankNode() :  { Token t = null ; }
{
  t = <BLANK_NODE_LABEL>
    { return createBNode(t.image, t.beginLine, t.beginColumn) ; }  
}

Node Literal() : { Node n ; }
{
  ( n = Number() | n = RDFLiteral() ) { return n ; }
}

Node RDFLiteral() : { Token t ; String lex = null ; }
{
  lex = String()
  // Optional lang tag and datatype.
  { String lang = null ; String dt = null ; }
  (
    lang = Langtag()
  |
    ( <DT> dt = IRIstr() )
  )?
    { return createLiteral(lex, lang, dt) ; }
} 

String Langtag() : { Token t ; }
{
  // Enumerate the directives here because they look like language tags.
  ( t = <LANGTAG> )
  { String lang = stripChars(t.image, 1) ; return lang ; }
}

Node Number() : { Token t ; }
{
  t = <INTEGER> 		    { return createLiteralInteger(t.image) ; }
| t = <DECIMAL>			    { return createLiteralDecimal(t.image) ; }
| t = <DOUBLE>			    { return createLiteralDouble(t.image) ; }
| t = <POSITIVE_INTEGER>	{ return createLiteralInteger(t.image) ; }
| t = <POSITIVE_DECIMAL>	{ return createLiteralDecimal(t.image) ; }
| t = <POSITIVE_DOUBLE>		{ return createLiteralDouble(t.image) ; }
| t = <NEGATIVE_INTEGER>	{ return createLiteralInteger(t.image) ; }
| t = <NEGATIVE_DECIMAL>	{ return createLiteralDecimal(t.image) ; }
| t = <NEGATIVE_DOUBLE>		{ return createLiteralDouble(t.image) ; }
}

String String() : { Token t ;  String lex ; }
{
//   ( t = <STRING1> { lex = stripQuotes(t.image) ; }
//   | t = <STRING2> { lex = stripQuotes(t.image) ; }
//   | t = <STRING_LONG1> { lex = stripQuotes3(t.image) ; }
//   | t = <STRING_LONG2> { lex = stripQuotes3(t.image) ; }
//   )

    ( t = <STRING1> | t = <STRING2> ) { lex = stripQuotes(t.image) ; }
    { lex = unescapeStr(lex,  t.beginLine, t.beginColumn) ;
      return lex ;
    }
}

SKIP : { <" " | "\t" | "\n" | "\r" | "\f"> }
//TOKEN: { <WS: " " | "\t" | "\n" | "\r" | "\f"> }

SPECIAL_TOKEN :
{ <SINGLE_LINE_COMMENT: "#" (~["\n","\r"])* ("\n"|"\r"|"\r\n")? > }

TOKEN :
{
  <DOT:		"." >
| <DT:      "^^" >
| <AT:      "@" >
| <PLUS:	"+" >
| <MINUS:	"-" >

| <ECHAR: "\\" ( "t"|"b"|"n"|"r"|"f"|"\\"|"\""|"'") >
//| <ECHAR: "\\" ( "t"|"b"|"n"|"r"|"f"|"\\"|"\""|"'"|"u") >
// | < #QUOTE_3D: "\"\"\"">
// | < #QUOTE_3S: "'''">

| < STRING1: 
      // Single quoted string
      "'" ( (~["'","\\","\n","\r"]) | <ECHAR> )* "'" > 
| < STRING2:
    // Double quoted string
      "\"" ( (~["\"","\\","\n","\r"]) | <ECHAR> )* "\"" >

// | < STRING_LONG1:
//      <QUOTE_3S> 
//       ( ("'" | "''")? (~["'","\\"] | <ECHAR> ))*
//      <QUOTE_3S> >
// | < STRING_LONG2: 
//      <QUOTE_3D> 
//       ( ("\"" | "\"\"")? (~["\"","\\"] | <ECHAR> ))*
//      <QUOTE_3D> >

| < #DIGITS: (["0"-"9"])+>
| < INTEGER: <DIGITS> >

| < DECIMAL: ( <DIGITS> "." (<DIGITS>)* | <DOT> <DIGITS> ) >
| < DOUBLE:   // Required exponent.
      (
        (["0"-"9"])+ "." (["0"-"9"])* <EXPONENT>
        | "." (["0"-"9"])+ (<EXPONENT>)
        | (["0"-"9"])+ <EXPONENT>
      )
      >

| < POSITIVE_INTEGER: <PLUS> <INTEGER> >
| < POSITIVE_DECIMAL: <PLUS> <DECIMAL> >
| < POSITIVE_DOUBLE:  <PLUS> <DOUBLE> >

| < NEGATIVE_INTEGER: <MINUS> <INTEGER> >
| < NEGATIVE_DECIMAL: <MINUS> <DECIMAL> >
| < NEGATIVE_DOUBLE:  <MINUS> <DOUBLE> >

| < #EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >


//| <IRIREF: "<" (~[ ">","<", "\"", "{", "}", "^", "\\", "|", "`",
//                      "\u0000"-"\u0020"])* ">" >
// Very liberal
| <IRIREF: "<" (~[">","<", " ", "\t", "\n", "\r", "\f" ])* ">" >

// Very liberal
| <BLANK_NODE_LABEL: "_:" (~[" ", "\t", "\n", "\r", "\f"])* >

| <LANGTAG: <AT> (<A2Z>)+("-" (<A2ZN>)+)* >
| <#A2Z: ["a"-"z","A"-"Z"]>
| <#A2ZN: ["a"-"z","A"-"Z","0"-"9"]>
}

// Catch-all tokens.  Must be last.  
// Any non-whitespace.  Causes a parser exception, rather than a
// token manager error (with hidden line numbers).
TOKEN:
{
  <#UNKNOWN: (~[" ","\t","\n","\r","\f" ])+ >
}

/*
 * (c) Copyright 2009 Hewlett-Packard Development Company, LP
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. The name of the author may not be used to endorse or promote products
 *    derived from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
/*
# Local Variables:
# tab-width: 4
# indent-tabs-mode: nil
# comment-default-style: "//"
# End:
*/