#!/usr/local/bin/perl -T

use strict;
use CGI qw(standard);

# The master list of data and how we tranform it into the xml we need.
#  0 - the form fieldname
#  1 - the xml tag name to use
#  2 - attribute name if applicable
#  3 - whether it's a URL, 1 = yes (append http:// if rqd), 0 = no
#  4 - printf format string to use for data
#
my @formData = (
    [ 'name', 'name', '', 0, 'Apache %s' ],
    [ 'homepage', 'homepage', 'rdf:resource', 1 ],
    [ 'pmc', 'asfext:pmc', 'rdf:resource', 0, 'http://%s.apache.org' ],
    [ 'sdesc', 'shortdesc' ],
    [ 'ldesc', 'description' ],
    [ 'bugdb', 'bug-database', 'rdf:resource', 1 ],
    [ 'mail', 'mailing-list', 'rdf:resource', 1 ],
    [ 'dl', 'download-page', 'rdf:resource', 1 ],
    [ 'lang', 'programming-language' ],
    [ 'cat', 'category', 'rdf:resource', 0, 'http://projects.apache.org/category/%s' ],
);

my $q = new CGI;
my @dtp = gmtime();
my $dt = sprintf("%d-%02d-%02d", $dtp[5] + 1900, $dtp[4] + 1, $dtp[3] );
my $projName = $q->param('name') || 'projectName';

my $thehomepage = makeURL($q->param('homepage'));

# $projName is used in the response headers; ensure the name is safe as a file name 
$projName =~ s/[^\w-]/_/g; # Keep only alphanumeric and -; convert rest to underscore
$projName .= '.rdf';

print <<EOF;
Content-type: application/rdf+xml
Content-Disposition: attachment; filename=doap_$projName

<?xml version="1.0"?>
<?xml-stylesheet type="text/xsl"?>
<rdf:RDF xml:lang="en"
         xmlns="http://usefulinc.com/ns/doap#" 
         xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
         xmlns:asfext="http://projects.apache.org/ns/asfext#"
         xmlns:foaf="http://xmlns.com/foaf/0.1/">
<!--
    Licensed to the Apache Software Foundation (ASF) under one or more
    contributor license agreements.  See the NOTICE file distributed with
    this work for additional information regarding copyright ownership.
    The ASF licenses this file to You under the Apache License, Version 2.0
    (the "License"); you may not use this file except in compliance with
    the License.  You may obtain a copy of the License at
   
         http://www.apache.org/licenses/LICENSE-2.0
   
    Unless required by applicable law or agreed to in writing, software
    distributed under the License is distributed on an "AS IS" BASIS,
    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
    See the License for the specific language governing permissions and
    limitations under the License.
-->
  <Project rdf:about="$thehomepage">
    <created>$dt</created>
    <license rdf:resource="http://spdx.org/licenses/Apache-2.0" />
EOF

for my $i (0 .. $#formData) {
    next unless (my $val = $q->param($formData[$i][0]));
    addData($val, $i);
}

if ($q->param('relname')) {
    my $n = $q->param('relname');
    my $d = $q->param('reldt');
    my $v = $q->param('relvers');
    print <<EOF;
    <release>
      <Version>
        <name>$n</name>
        <created>$d</created>
        <revision>$v</revision>
      </Version>
    </release>
EOF
}
if ($q->param('svnurl')) {
    my $s = $q->param('svnurl');
    my $v = $q->param('svnhttp');
    $s = 'http://'.$s unless $s =~ /^http/;
    $v = 'http://'.$v unless $v =~ /^http/;
    print <<EOF;
    <repository>
      <SVNRepository>
        <location rdf:resource="$s"/>
        <browse rdf:resource="$v"/>
      </SVNRepository>
    </repository>
EOF
}
if ($q->param('giturl')) {
    my $s = $q->param('giturl');
    my $v = $q->param('githttp');
    print <<EOF;
    <repository>
      <GitRepository>
        <location rdf:resource="$s"/>
        <browse rdf:resource="$v"/>
      </GitRepository>
    </repository>
EOF
}
if ($q->param('maintainer_name')) {
    my $name = $q->param('maintainer_name');
    my $email = $q->param('maintainer_email');
    print <<EOF;
    <maintainer>
      <foaf:Person>
        <foaf:name>$name</foaf:name>
          <foaf:mbox rdf:resource="mailto:$email"/>
      </foaf:Person>
    </maintainer>
EOF
}
if ($q->param('std_title')) {
    my $t = $q->param('std_title');
    my $b = $q->param('std_body');
    my $i = $q->param('std_id');
    my $u = makeURL($q->param('std_url'));
    print <<EOF;
    <asfext:implements><asfext:Standard>
      <asfext:title>$t</asfext:title>
      <asfext:body>$b</asfext:body>
      <asfext:id>$i</asfext:id>
      <asfext:url rdf:resource="$u"/>
    </asfext:Standard></asfext:implements>
EOF
}


print <<EOF;
  </Project>
</rdf:RDF>
EOF

exit;

sub addData
{
    my ($val, $i) = @_;

    print "    <$formData[$i][1]";
    print " $formData[$i][2]=\"" if $formData[$i][2];
    print ">" unless $formData[$i][2];
    $val = makeURL($val) if $formData[$i][3];
    if ($formData[$i][4]) {
        printf($formData[$i][4], $val);
    } else {
        print $val;
    }
    print "\" />" if $formData[$i][2];
    print "</$formData[$i][1]>" unless $formData[$i][2];
    print "\n";
}

sub makeURL
{
    my $u = shift;
    $u = 'http://'.$u unless $u =~ /^http/;
    return $u;
}