AC_INIT(javahl, 0.32.1)
dnl this writes a "config.nice" file which reinvokes ./configure with all
dnl of the arguments. this is different from config.status which simply
dnl regenerates the output files. config.nice is useful after you rebuild
dnl ./configure (via autoconf or autogen.sh)
AC_DEFUN(SVN_CONFIG_NICE,[
  echo creating $1
  rm -f $1
  cat >$1<<EOF
#! /bin/sh
#
# Created by configure
EOF

  for arg in [$]0 "[$]@"; do
    echo "\"[$]arg\" \\" >> $1
  done
  echo '"[$]@"' >> $1
  chmod +x $1
])


SVN_CONFIG_NICE(config.nice)

sinclude(../../../../build/ac-macros/java.m4)
sinclude(../../../../build/ac-macros/find_apr.m4)
sinclude(../../../../build/ac-macros/find_apu.m4)

AM_INIT_AUTOMAKE(javahl, 0.32.1)
AM_MAINTAINER_MODE

APR_FIND_APR("../../../../apr","../../../../apr",1)
APR_FIND_APU("../../../../apr-util","../../../../apr-util",1)

APRCONFIG=$apr_config
APUCONFIG=$apu_config

AC_PROG_CXX
AC_PROG_INSTALL
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
dnl
dnl SVN
dnl
SVNCONFIG=../../../../svn-config
CXXFLAGS="$CXXFLAGS `$APRCONFIG --cflags` `$APRCONFIG --cppflags` \
                    `$APRCONFIG --includes` `$APUCONFIG --includes` -I../../../../include"
SVN_LIBS="`$APUCONFIG --libs` `$APRCONFIG --libs`"
dnl SVN_PREFIX="`$SVNCONFIG --prefix`"
dnl SVN_LIBS="$SVN_LIBS -L$SVN_PREFIX/lib -lsvn_client-1 -lsvn_delta-1 -lsvn_fs-1 -lsvn_ra-1 -lsvn_ra_dav-1 -lsvn_ra_local-1 -lsvn_ra_svn-1 -lsvn_repos-1 -lsvn_subr-1 -lsvn_wc-1"
SVN_LIBS="$SVN_LIBS ../../../../libsvn_client/libsvn_client-1.la"
SVN_CHECK_JDK
    if test "$JDK" != "none" -a "$JDK_SUITABLE" = "yes"; then
      list="`find "$JDK/include" -type d -print`"
      for dir in $list; do
        JAVA_INCLUDES="$JAVA_INCLUDES -I$dir"
      done
    fi

CXXFLAGS="$CXXFLAGS $JAVA_INCLUDES"
CFLAGS="$CFLAGS $JAVA_INCLUDES"
 
AC_SUBST(SVN_LIBS)

AC_CONFIG_FILES(Makefile src/Makefile native/Makefile cls/Makefile doc/Makefile)
AC_OUTPUT