Esimerkki 1: tekstiasiakirjan otsikoiden tulostaminen

Tämä esimerkki tulostaa tekstiasiakirjan kaikki otsikot tekstitiedostoon, sisentäen otsikkotason mukaan. Se toimii kaikilla OpenOffice.org 1.1.x Writer (.sxw) -asiakirjoilla.

Tämä on tehty OpenOffice.org 1.1:llä!. OpenOffice.org 2.0:n OASIS OpenDocument -asiakirjan käsittely vaatii mm. hieman erilaiset nimiavaruusmäärittelyt.

XSLT-ohjelma

<?xml version="1.0" encoding="ISO-8859-1"?>

<!-- ======================================================================== -->
<!-- OpenOffice 1.1:n nimiavaruusmäärittelyt                                  -->
<!-- Huomaa, että tähän on otettu mukaan vain ne nimiavaruudet, joita tässä   -->
<!-- muunnoksessa oikeasti käytetään.                                         -->
<!-- ======================================================================== -->
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:office="http://openoffice.org/2000/office"
  xmlns:style="http://openoffice.org/2000/style"
  xmlns:text="http://openoffice.org/2000/text"
  office:class="text"
  office:version="1.0"
  version="1.0">

  <!-- Määrätään muunnoksen ulostulomuoto ja merkkikoodaus. -->
  <xsl:output method="text" encoding="ISO-8859-1"/>

  <!-- ======================================================================== -->
  <!-- Tee muotoilu otsikon text:level-kentässä olevan numeron mukaan           -->
  <!-- ======================================================================== -->
  <xsl:template match="text:h">
    <xsl:if test="normalize-space(.) != ''">
      <xsl:value-of select="substring('          ', 1, (number(@text:level)-1)*2)"/>
      <xsl:text>* </xsl:text>
      <xsl:value-of select="."/>
      <xsl:text>&#x0a;</xsl:text>
    </xsl:if>
  </xsl:template>


  <!-- ======================================================================== -->
  <!-- Juurisolmu                                                               -->
  <!-- ======================================================================== -->
   <xsl:template match="/">
     <xsl:text>ASIAKIRJAN OTSIKOT&#x0a;</xsl:text>
     <xsl:apply-templates/>
   </xsl:template>

  <!-- ======================================================================== -->
  <!-- Karsitaan pois kaikki muut tekstit                                       -->
  <!-- ======================================================================== -->
   <xsl:template match="text()">
   </xsl:template>

</xsl:stylesheet>

XSLT-muunnoksen tekeminen asiakirjalle

XML-ohjelmaa voi käyttää Linuxissa komentoriviltä seuraavasti, mikäli xsltproc-ohjelma on asennettuna. Puretaan asiakirjasta ensin sen sisältö ja sen jälkeen ajetaan nimellä otsikot.xsl tallennettu XSLT-ohjelma.

$ unzip Asennusohje.sxw content.xml
$ xsltproc otsikot.xsl content.xml

XSLT-ohjelman voi myös asentaa OpenOffice.orgiin vientisuodattimeksi. Myös Mozilla Firefox -selain tukee XSLT-tyylisivuja, joten content.xml-tiedostoa on (siihen tehtävän tyylisivumäärityksen jälkeen) mahdollista katsoa selaimella muunnetussa muodossa.

Esimerkkituloste

Alla esimerkkituloste OpenOffice.org 1.1:n asennusohjeesta (Zip-paketti, joka sisältää OpenOffice.org 1.1 Writer -asiakirjan ja leikekuvia).

ASIAKIRJAN OTSIKOT
* Tästä ohjeesta
  * Tässä ohjeessa käytetyt kuvakkeet
* Yleistä tietoa asennuksesta
  * Asennustyypit
  * Järjestelmän vaatimukset 
    * Yleiset järjestelmän vaatimukset
    * Erityisvaatimukset Solaris™-käyttöjärjestelmälle
    * Erityisvaatimukset Linux-käyttöjärjestelmälle
  * Ladatun asennuspaketin sisältö 
  * Ennen kuin asennat ladatun ohjelmiston
  * Olemassa olevan asennuksen päivittäminen 
    * Usean käyttäjän asennuksen päivittäminen
* Yhden käyttäjän asennus 
  * Asennusvaatimukset
  * Asennuksen aloittaminen
    * Asentaminen CD-levyltä UNIX-järjestelmissä
    * Asennus käyttäen ladattuja asennuspaketteja UNIX-ympäristössä
    * Asennus CD-levyltä Windows-järjestelmässä (käyttäen versiota 1.1.3 tai uudempaa)
    * Asennus CD-levyltä Windows-järjestelmässä (käyttäen aiempaa versiota kuin 1.1.3)
    * Asennus käyttäen ladattuja asennuspaketteja Windows-ympäristössä
  * Asennusvaiheet
    * Tervetuloa
    * Tärkeää
    * Lisenssin hyväksyminen
    * Käyttäjätiedot
    * Asennustyyppi
    * Asennettavien osien valinta 
    * Asennuskansio
    * Asennusvaihtoehtojen tarkastus
    * Tiedostotyyppien kytkeminen
    * Java™-ajoympäristön asennus
    * Tiedostojen kopiointi
    * Asennuksen päättäminen
  * OpenOffice.org-ohjelman käynnistäminen
* Usean käyttäjän asennus ja verkkoasennus 
  * Palvelinasennus 
    * Asennuksen vähimmäisvaatimukset
    * Asennuksen aloittaminen
      * CD-levyltä asentaminen Linux- tai UNIX-käyttöjärjestelmässä
      * Asennuksen aloitus käyttäen ladattuja asennuspaketteja Linux- tai UNIX-käyttöjärjestelmässä
      * CD-levyltä asennus Windows-järjestelmässä
      * Asennuksen aloitus käyttäen ladattuja asennuspaketteja Windows ympä­ristössä
  * Asennusvaiheet
    * Tervetuloa
    * Tärkeitä tietoja
    * Lisenssin hyväksyminen
    * Asennustyyppi
    * Osien valinta 
    * Asennuskansio
    * Java™-ajoympäristön asennus 
    * Asennusvaihtoehtojen tarkastus
    * Tiedostojen kopiointi
    * Asennuksen päättäminen
  * Työasema-asennus
    * Asennusvaatimukset
    * Asennuksen aloitus
      * Asennus UNIX-järjestelmään
      * Asennus Windows-järjestelmiin
  * Asennusvaiheet
    * Tervetuloa
    * Tärkeitä tietoja
    * Lisenssin hyväksyminen
    * Käyttäjätiedot
    * Asennustyyppi
    * Asennuskansio
    * Asennusvaihtoehtojen tarkastus
    * Tiedostotyyppien kytkeminen
    * Java™-ajoympäristön asennus
    * Tiedostojen kopiointi
    * Asennuksen päättäminen
  * OpenOffice.org-ohjelmiston käynnistäminen
* Liite
  * Java™-ajoympäristön asennus Windows-jär­jestelmään
  * Tulostimen, faksin ja fonttien asentaminen UNIX®-pohjaisissa käyttöjärjestelmissä
    * Tulostinten asentaminen
      * Tulostimen lisääminen
      * OpenOffice.org ohjelmiston tulostinajurit
        * Ajureiden tuonti kun luot uutta tulostinta
        * Ajurin poistaminen uutta tulostinta luotaessa
      * Tulostusasetuksien muuttaminen
      * Tulostimien uudelleennimeäminen tai poistaminen
    * Fax toiminnon käyttäminen
    * Postscriptin kytkeminen PDF konvertteriin
    * Fonttien asennus
      * Fonttien lisääminen
      * Fonttien poistaminen
      * Fonttien uudelleennimeäminen
  * Korjaustiedoston asentaminen Solaris™ ympä­ristöön
  * Olemassa olevan OpenOffice.Org asennuksen muokkaaminen 
    * Muuta 
    * Korjaa
    * Poista 
  * Asennusparametrit
  * OpenOffice.org ohjelman käynnistäminen pa­rametrin kanssa
    * OpenOffice.org ohjelman käynnistäminen komentoriviltä
    * Komentorivi parametrit
  * OpenOffice.org ohjelman rekisteröinti
  * OpenOffice.org ohjelman laajentaminen
    * Laajennosten asentaminen, päivittäminen ja poistaminen yksittäiseltä käyttäjältä
    * Lisäosien asentaminen, päivittäminen ja poistaminen usean käyttäjän asennuksessa

Marko Grönroos
magi42@openoffice.org