!ifndef _WriteEnvStr_nsh
!define _WriteEnvStr_nsh
 
!include WinMessages.nsh

#
# WriteEnvStr - Writes an environment variable
# Note: Win9x systems requires reboot
#
# Example:
#  Push "HOMEDIR"           # name
#  Push "C:\New Home Dir\"  # value
#  Call WriteEnvStr
#
Function WriteEnvStr
  Exch $1 ; $1 has environment variable value
  Exch
  Exch $0 ; $0 has environment variable name
  Push $2

  Call IsNT
  Pop $2
  StrCmp $2 1 WriteEnvStr_NT
    ; Not on NT
    StrCpy $2 $WINDIR 2 ; Copy drive of windows (c:)
    FileOpen $2 "$2\autoexec.bat" a
    FileSeek $2 0 END
    FileWrite $2 "$\r$\nSET $0=$1$\r$\n"
    FileClose $2
    SetRebootFlag true
    DetailPrint "Environment variable $0 setted to $1."
    Goto WriteEnvStr_done

  WriteEnvStr_NT:
      ; Set it locally for the installer
      SetEnv::SetEnvVar $0 $1
      Call IsAdmin
      Pop $2
      StrCmp $2 1 +3
      WriteRegExpandStr HKCU "Environment" $0 $1
      Goto +2
      WriteRegExpandStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" $0 $1
      DetailPrint "Environment variable $0 setted to $1."
      SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} \
        0 "STR:Environment" /TIMEOUT=5000
  WriteEnvStr_done:
    Pop $2
    Pop $0
    Pop $1
FunctionEnd
 
#
# un.DeleteEnvStr - Removes an environment variable
# Note: Win9x systems requires reboot
#
# Example:
#  Push "HOMEDIR"           # name
#  Call un.DeleteEnvStr
#
Function un.DeleteEnvStr
  Exch $0 ; $0 now has the name of the variable
  Push $1
  Push $2
  Push $3
  Push $4
  Push $5
 
  Call un.IsNT
  Pop $1
  StrCmp $1 1 DeleteEnvStr_NT
    ; Not on NT
    StrCpy $1 $WINDIR 2
    FileOpen $1 "$1\autoexec.bat" r
    GetTempFileName $4
    FileOpen $2 $4 w
    StrCpy $0 "SET $0="
    SetRebootFlag true
 
    DeleteEnvStr_dosLoop:
      FileRead $1 $3
      StrLen $5 $0
      StrCpy $5 $3 $5
      StrCmp $5 $0 DeleteEnvStr_dosLoop
      StrCmp $5 "" DeleteEnvStr_dosLoopEnd
      FileWrite $2 $3
      Goto DeleteEnvStr_dosLoop
 
    DeleteEnvStr_dosLoopEnd:
      FileClose $2
      FileClose $1
      StrCpy $1 $WINDIR 2
      Delete "$1\autoexec.bat"
      CopyFiles /SILENT $4 "$1\autoexec.bat"
      Delete $4
      Goto DeleteEnvStr_done
 
  DeleteEnvStr_NT:
    Call un.IsAdmin
    Pop $1
    StrCmp $1 1 +3
    DeleteRegValue HKCU "Environment" $0
    Goto +2
    DeleteRegValue HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" $0
    SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} \
      0 "STR:Environment" /TIMEOUT=5000
 
  DeleteEnvStr_done:
    Pop $5
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
FunctionEnd

; http://nsis.sourceforge.net/wiki/Path_Manipulation
; Modified By AHE :
; - Add logs in functions
; - Try to expand env var before to addToPath to see if it exist

; AddToPath - Adds the given dir to the search path.
;        Input - head of the stack
;        Note - Win9x systems requires reboot

Function AddToPath
  Exch $0
  Push $1
  Push $2
  Push $3

  ; Workaround for windows bug : http://support.microsoft.com/kb/329308
  ExpandEnvStrings $0 $0

  # don't add if the path doesn't exist
  ExpandEnvStrings $2 $0
  !ifdef DEBUG
    DetailPrint 'To test : "$2"'
  !endif
  GetFullPathName $2 $2
  !ifdef DEBUG
    DetailPrint 'To test : "$2"'
  !endif
  IfFileExists $2\*.* +3 0
  DetailPrint "$0 not added to the PATH. $2 doesn't exist."
  Goto AddToPath_done

  ReadEnvStr $1 PATH
  
  Push "$1;"
  Push "$0;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$0;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done
  Push "$1;"
  Push "$0\;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$0\;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done

  ExpandEnvStrings $3 $0
  Push "$1;"
  Push "$3;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$3;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done
  Push "$1;"
  Push "$3\;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$3\;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done
  
  ExpandEnvStrings $3 $0
  GetFullPathName /SHORT $3 $3
  Push "$1;"
  Push "$3;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$3;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done
  Push "$1;"
  Push "$3\;"
  !ifdef DEBUG
    DetailPrint 'Compare "$1;" with "$3\;"'
  !endif
  Call StrStr
  Pop $2
  !ifdef DEBUG
    DetailPrint 'Result : $2'
  !endif
  StrCmp $2 ""  +3 0
  DetailPrint "$0 not added to the PATH. $0 already present."
  Goto AddToPath_done

  Call IsNT
  Pop $1
  StrCmp $1 1 AddToPath_NT
    ; Not on NT
    StrCpy $1 $WINDIR 2
    FileOpen $1 "$1\autoexec.bat" a
    FileSeek $1 -1 END
    FileReadByte $1 $2
    IntCmp $2 26 0 +2 +2 # DOS EOF
      FileSeek $1 -1 END # write over EOF
    FileWrite $1 "$\r$\nSET PATH=$3;%PATH%$\r$\n"
    FileClose $1
    SetRebootFlag true
    DetailPrint "$0 added to the PATH."
    Goto AddToPath_done

  AddToPath_NT:
  
    Call IsAdmin
    Pop $2
    StrCmp $2 1 +3
    ReadRegStr $1 HKCU "Environment" "PATH"
    Goto +2
    ReadRegStr $1 HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "PATH"
    StrCpy $3 "$0;$1"
	  DetailPrint "$0 added to the PATH."
	  Call IsAdmin
	  Pop $2
	  StrCmp $2 1 +3
	  WriteRegExpandStr HKCU "Environment" "PATH" $3
	  Goto +2
	  WriteRegExpandStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "PATH" $3
	  SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000

  AddToPath_done:
    Pop $3
    Pop $2
    Pop $1
    Pop $0
FunctionEnd

; RemoveFromPath - Remove a given dir from the path
;     Input: head of the stack

Function un.RemoveFromPath
  Exch $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $5
  Push $6

  ; Workaround for windows bug : http://support.microsoft.com/kb/329308
  ExpandEnvStrings $0 $0

  DetailPrint "$0 will be removed from PATH."

  IntFmt $6 "%c" 26 # DOS EOF

  Call un.IsNT
  Pop $1
  StrCmp $1 1 unRemoveFromPath_NT
    ; Not on NT
    StrCpy $1 $WINDIR 2
    FileOpen $1 "$1\autoexec.bat" r
    GetTempFileName $4
    FileOpen $2 $4 w
    GetFullPathName /SHORT $0 $0
    StrCpy $0 "SET PATH=%PATH%;$0"
    Goto unRemoveFromPath_dosLoop

    unRemoveFromPath_dosLoop:
      FileRead $1 $3
      StrCpy $5 $3 1 -1 # read last char
      StrCmp $5 $6 0 +2 # if DOS EOF
        StrCpy $3 $3 -1 # remove DOS EOF so we can compare
      StrCmp $3 "$0$\r$\n" unRemoveFromPath_dosLoopRemoveLine
      StrCmp $3 "$0$\n" unRemoveFromPath_dosLoopRemoveLine
      StrCmp $3 "$0" unRemoveFromPath_dosLoopRemoveLine
      StrCmp $3 "" unRemoveFromPath_dosLoopEnd
      FileWrite $2 $3
      Goto unRemoveFromPath_dosLoop
      unRemoveFromPath_dosLoopRemoveLine:
        SetRebootFlag true
        Goto unRemoveFromPath_dosLoop

    unRemoveFromPath_dosLoopEnd:
      FileClose $2
      FileClose $1
      StrCpy $1 $WINDIR 2
      Delete "$1\autoexec.bat"
      CopyFiles /SILENT $4 "$1\autoexec.bat"
      Delete $4
      Goto unRemoveFromPath_done

  unRemoveFromPath_NT:
  
	  Call un.IsAdmin
	  Pop $2
	  StrCmp $2 1 +3
    ReadRegStr $1 HKCU "Environment" "PATH"
	  Goto +2
    ReadRegStr $1 HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "PATH"  
    StrCpy $5 $1 1 -1 # copy last char
    StrCmp $5 ";" +2 # if last char != ;
      StrCpy $1 "$1;" # append ;
    Push $1
    Push "$0;"
    Call un.StrStr ; Find `$0;` in $1
    Pop $2 ; pos of our dir
    StrCmp $2 "" unRemoveFromPath_done
      ; else, it is in path
      # $0 - path to add
      # $1 - path var
      StrLen $3 "$0;"
      StrLen $4 $2
      StrCpy $5 $1 -$4 # $5 is now the part before the path to remove
      StrCpy $6 $2 "" $3 # $6 is now the part after the path to remove
      StrCpy $3 $5$6
      StrCpy $5 $3 1 -1 # copy last char
      StrCmp $5 ";" 0 +2 # if last char == ;
      StrCpy $3 $3 -1 # remove last char
      Call un.IsAdmin
      Pop $2
      StrCmp $2 1 +3
      WriteRegExpandStr HKCU "Environment" "PATH" $3
      Goto +2
      WriteRegExpandStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "PATH" $3
      SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=5000

  unRemoveFromPath_done:
    Pop $6
    Pop $5
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
FunctionEnd

!ifndef IsNT_KiCHiK
!define IsNT_KiCHiK

###########################################
#            Utility Functions            #
###########################################

; IsNT
; no input
; output, top of the stack = 1 if NT or 0 if not
;
; Usage:
;   Call IsNT
;   Pop $R0
;  ($R0 at this point is 1 or 0)

!macro IsNT un
Function ${un}IsNT
  Push $0
  ReadRegStr $0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" CurrentVersion
  StrCmp $0 "" 0 IsNT_yes
  ; we are not NT.
  Pop $0
  Push 0
  Return

  IsNT_yes:
    ; NT!!!
    Pop $0
    Push 1
FunctionEnd
!macroend
!insertmacro IsNT ""
!insertmacro IsNT "un."

!endif ; IsNT_KiCHiK

; StrStr
; input, top of stack = string to search for
;        top of stack-1 = string to search in
; output, top of stack (replaces with the portion of the string remaining)
; modifies no other variables.
;
; Usage:
;   Push "this is a long ass string"
;   Push "ass"
;   Call StrStr
;   Pop $R0
;  ($R0 at this point is "ass string")

!macro StrStr un
Function ${un}StrStr
Exch $R1 ; st=haystack,old$R1, $R1=needle
  Exch    ; st=old$R1,haystack
  Exch $R2 ; st=old$R1,old$R2, $R2=haystack
  Push $R3
  Push $R4
  Push $R5
  StrLen $R3 $R1
  StrCpy $R4 0
  ; $R1=needle
  ; $R2=haystack
  ; $R3=len(needle)
  ; $R4=cnt
  ; $R5=tmp
  loop:
    StrCpy $R5 $R2 $R3 $R4
    StrCmp $R5 $R1 done
    StrCmp $R5 "" done
    IntOp $R4 $R4 + 1
    Goto loop
done:
  StrCpy $R1 $R2 "" $R4
  Pop $R5
  Pop $R4
  Pop $R3
  Pop $R2
  Exch $R1
FunctionEnd
!macroend
!insertmacro StrStr ""
!insertmacro StrStr "un."
 
#
# [un.]IsAdmin - Pushes 1 if users has admin rights, 0 if not
#
# Example:
#   Call IsAdmin
#   Pop $0
#   StrCmp $0 1 +3
#     MessageBox MB_OK "You are not administrator!"
#     Goto +2
#     MessageBox MB_OK "You are administrator!"
#
!macro IsAdmin UN
Function ${UN}IsAdmin
  Push $0
  System::Call "kernel32::GetModuleHandle(t 'shell32.dll') i .s"
  System::Call "kernel32::GetProcAddress(i s, i 680) i .r0"
  System::Call "::$0() i .r0"
  StrCmp $0 "" 0 +4
  Pop $0
  Push 0
  Return
  Pop $0
  Push 1
  Return
FunctionEnd
!macroend
!insertmacro IsAdmin ""
!insertmacro IsAdmin "un."

!endif ; _WriteEnvStr_nsh